Arma 3のUAV画面からミッションを開始する

Arma 3のショーケースのイントロで使用されている、UAVの画面からミッションを開始するのを使ってみよう。

目標を設定する事により好きな場所を表示させられる事が可能で、表示されるテキストには日本語も使用可能。

ミッションのフォルダにinit.sqfを作成したら、下記の構文をコピペするだけで完成。

0 fadeSound 0;
0 fadeMusic 0;
enableRadio false;
enableEnvironment false;
clearRadio;
// Establish Shot

private ["_colorWest", "_colorEast"];

_colorWest = WEST call BIS_fnc_sideColor;
_colorEast = EAST call BIS_fnc_sideColor;

{
    _x set [3, 0.33]
} forEach [_colorWest, _colorEast];

introShot = [
    markerPos "tower1Mrk", // Target position マップ マーカーの名前
    "通信塔を破壊せよ", // SITREP text
    300, // 300m altitude UAVの高度
    300, // 300m radius 旋回半径
    90, // 90 degrees viewing angle カメラの見下ろす角度
    0, // clockwise movement
    [
        ["\a3\ui_f\data\map\markers\nato\o_inf.paa", _colorWest, markerPos "insertMrk", 1, 1, 0, "Insertion Point", 0],
        ["\a3\ui_f\data\map\markers\nato\o_inf.paa", _colorEast, markerPos "towerBaseMrk", 1, 1, 0, "Radio Towers", 0]
    ]
] spawn BIS_fnc_establishingShot;
waitUntil {scriptDone introShot};

//画面表示が終わったら、音楽と音声を再生させる

playMusic "Track09_Night_percussions";

sleep 5;
5 fadeSound 0.4;
5 fadeMusic 0.18;
enableRadio true;
enableEnvironment true;

以上！SITREP textの所を変更して、文章を表示させよう。但し、ファイルの文字エンコーディングを“UTF-8”で保存しないと、文字化けします。